(AC_STRUCT_ST_RDEV, AC_STRUCT_ST_BLKSIZE): No longer use these.

Instead use AC_CHECK_MEMBERS.

(AC_STRUCT_ST_BLOCKS): Use instead of ad-hoc test.

Use AC_PREREQ, AC_INIT and AC_CONFIG_SRCDIR sequence
instead of lone AC_INIT.

Use AC_CONFIG_FILES, AC_CONFIG_COMMANDS and AC_OUTPUT sequence
instead of lone AC_OUTPUT.

(AC_CONFIG_FILES): Add test-suite/Makefile and check-guile.
(AC_CONFIG_COMMANDS): Also chmod +x check-guile.

configure.in

@@ -20,7 +20,10 @@ dnl  along with GUILE; see the file COPYING.  If not, write to the
 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
 dnl  Boston, MA 02111-1307, USA.
 
-AC_INIT(Makefile.in)
+AC_PREREQ(2.50)
+
+AC_INIT
+AC_CONFIG_SRCDIR([Makefile.in])
 . $srcdir/GUILE-VERSION
 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
 AM_MAINTAINER_MODE
@@ -185,7 +188,7 @@ AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mkno
 AC_DEFUN(GUILE_FUNC_DECLARED, [
   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
     AC_EGREP_HEADER($1, $2,
-		    guile_cv_func_$1_declared=yes, 
+		    guile_cv_func_$1_declared=yes,
 		    guile_cv_func_$1_declared=no))
   if test [x$guile_cv_func_]$1[_declared] = xno; then
     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
@@ -234,7 +237,7 @@ dnl restore confdefs.h
 dnl cp confdefs.h confdefs.h.bak
 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof hstrerror; do
 dnl cp confdefs.h.bak confdefs.h
-dnl cat >> confdefs.h << EOF 
+dnl cat >> confdefs.h << EOF
 dnl #ifdef __CYGWIN32__
 dnl #define $func cygwin32_$func
 dnl #endif
@@ -336,18 +339,10 @@ AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 AC_FUNC_ALLOCA
 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 
-AC_STRUCT_ST_RDEV
-AC_STRUCT_ST_BLKSIZE
+AC_CHECK_MEMBERS([struct stat.st_rdev])
+AC_CHECK_MEMBERS([struct stat.st_blksize])
 
-# We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
-# LIBOBJS, which we don't need.  This seems more direct. 
-AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
-[AC_TRY_COMPILE([#include <sys/types.h>
-#include <sys/stat.h>], [struct stat s; s.st_blocks;],
-ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
-if test $ac_cv_struct_st_blocks = yes; then
-  AC_DEFINE(HAVE_ST_BLOCKS)
-fi
+AC_STRUCT_ST_BLOCKS
 
 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
   [AC_TRY_CPP([#include <sys/stat.h>
@@ -371,7 +366,7 @@ GUILE_STRUCT_UTIMBUF
 
 AC_TRY_RUN(aux (l) unsigned long l;
 	     { int x; exit (l >= ((unsigned long)&x)); }
-	   main () { int q; aux((unsigned long)&q); }, 
+	   main () { int q; aux((unsigned long)&q); },
 	   AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 
 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
@@ -522,7 +517,34 @@ AC_SUBST(AWK)
 AC_SUBST(LIBLOBJS)
 AC_SUBST(EXTRA_DOT_DOC_FILES)
 
-AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])
+AC_CONFIG_FILES([
+  Makefile
+  libguile/Makefile
+  libguile/guile-snarf
+  libguile/guile-doc-snarf
+  libguile/guile-func-name-check
+  libguile/guile-snarf.awk
+  libguile/versiondat.h
+  ice-9/Makefile
+  qt/Makefile
+  qt/qt.h
+  qt/md/Makefile
+  qt/time/Makefile
+  guile-config/Makefile
+  doc/Makefile
+  test-suite/Makefile
+  check-guile
+])
+
+AC_CONFIG_COMMANDS(default,[
+  chmod +x libguile/guile-snarf \
+           libguile/guile-doc-snarf \
+           libguile/guile-func-name-check \
+	   check-guile
+])
+
+AC_OUTPUT
+
 
 dnl Local Variables:
 dnl comment-start: "dnl "