mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-04-30 03:40:34 +02:00
f0007cade0
* m4/gnulib-cache.m4: Use `dirfd'. * libguile/filesys.c: Include Gnulib's <dirent.h> directly. (dirfd): Remove. Suggested by Bruno Haible <bruno@clisp.org>.
39 lines
1.2 KiB
Text
39 lines
1.2 KiB
Text
# rmdir.m4 serial 12
|
|
dnl Copyright (C) 2002, 2005, 2009-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_RMDIR],
|
|
[
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
dnl Detect cygwin 1.5.x bug.
|
|
AC_CHECK_HEADERS_ONCE([unistd.h])
|
|
AC_CACHE_CHECK([whether rmdir works], [gl_cv_func_rmdir_works],
|
|
[mkdir conftest.dir
|
|
touch conftest.file
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <stdio.h>
|
|
#include <errno.h>
|
|
#if HAVE_UNISTD_H
|
|
# include <unistd.h>
|
|
#else /* on Windows with MSVC */
|
|
# include <direct.h>
|
|
#endif
|
|
]], [[int result = 0;
|
|
if (!rmdir ("conftest.file/"))
|
|
result |= 1;
|
|
else if (errno != ENOTDIR)
|
|
result |= 2;
|
|
if (!rmdir ("conftest.dir/./"))
|
|
result |= 4;
|
|
return result;
|
|
]])],
|
|
[gl_cv_func_rmdir_works=yes], [gl_cv_func_rmdir_works=no],
|
|
[gl_cv_func_rmdir_works="guessing no"])
|
|
rm -rf conftest.dir conftest.file])
|
|
if test x"$gl_cv_func_rmdir_works" != xyes; then
|
|
REPLACE_RMDIR=1
|
|
fi
|
|
])
|