mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-19 19:20:23 +02:00
d1c83d388a
* module/rnrs/6/exceptions.scm: (guard0, guard): New syntax. * module/rnrs/records/6/procedural.scm: (r6rs-raise-continuable): Can't use `raise' here because it's exported by (rnrs exceptions); use plain old `throw' instead. * test-suite/Makefile.am: Add tests/r6rs-exceptions.test to SCM_TESTS. * test-suite/tests/r6rs-exceptions.test: New file.
72 lines
2.6 KiB
Scheme
72 lines
2.6 KiB
Scheme
;;; exceptions.scm --- The R6RS exceptions library
|
||
|
||
;; Copyright (C) 2010 Free Software Foundation, Inc.
|
||
;;
|
||
;; This library is free software; you can redistribute it and/or
|
||
;; modify it under the terms of the GNU Lesser General Public
|
||
;; License as published by the Free Software Foundation; either
|
||
;; version 3 of the License, or (at your option) any later version.
|
||
;;
|
||
;; This library is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
||
;; Lesser General Public License for more details.
|
||
;;
|
||
;; You should have received a copy of the GNU Lesser General Public
|
||
;; License along with this library; if not, write to the Free Software
|
||
;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
||
|
||
|
||
(library (rnrs exceptions (6))
|
||
(export guard with-exception-handler raise raise-continuable)
|
||
(import (rnrs base (6))
|
||
(rnrs conditions (6))
|
||
(rnrs records procedural (6))
|
||
(rnrs syntax-case (6))
|
||
(only (guile) with-throw-handler))
|
||
|
||
(define raise (@@ (rnrs records procedural) r6rs-raise))
|
||
(define raise-continuable
|
||
(@@ (rnrs records procedural) r6rs-raise-continuable))
|
||
(define raise-object-wrapper?
|
||
(@@ (rnrs records procedural) raise-object-wrapper?))
|
||
(define raise-object-wrapper-obj
|
||
(@@ (rnrs records procedural) raise-object-wrapper-obj))
|
||
(define raise-object-wrapper-continuation
|
||
(@@ (rnrs records procedural) raise-object-wrapper-continuation))
|
||
|
||
(define (with-exception-handler handler thunk)
|
||
(with-throw-handler 'r6rs:exception
|
||
thunk
|
||
(lambda (key . args)
|
||
(if (and (not (null? args))
|
||
(raise-object-wrapper? (car args)))
|
||
(let* ((cargs (car args))
|
||
(obj (raise-object-wrapper-obj cargs))
|
||
(continuation (raise-object-wrapper-continuation cargs))
|
||
(handler-return (handler obj)))
|
||
(if continuation
|
||
(continuation handler-return)
|
||
(raise (make-non-continuable-violation))))
|
||
*unspecified*))))
|
||
|
||
(define-syntax guard0
|
||
(lambda (stx)
|
||
(syntax-case stx ()
|
||
((_ (variable cond-clause ...) body)
|
||
(syntax (call/cc (lambda (continuation)
|
||
(with-exception-handler
|
||
(lambda (variable)
|
||
(continuation (cond cond-clause ...)))
|
||
(lambda () body)))))))))
|
||
|
||
(define-syntax guard
|
||
(lambda (stx)
|
||
(syntax-case stx (else)
|
||
((_ (variable cond-clause ... . ((else else-clause ...))) body)
|
||
(syntax (guard0 (variable cond-clause ... (else else-clause ...))
|
||
body)))
|
||
((_ (variable cond-clause ...) body)
|
||
(syntax (guard0 (variable cond-clause ... (else (raise variable)))
|
||
body))))))
|
||
)
|