mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-01 04:10:18 +02:00
f95f82f8e1
* module/ice-9/boot-9.scm (make-fresh-user-module): New public function, makes an anonymous beautified module. * module/language/objcode/spec.scm: We used to have some things in here that allowed lexical variable names and values to be a part of the environment, but no more. Now an environment is just a module. If you want to "inject" free variables into code, just use lambda. * module/language/scheme/compile-tree-il.scm (compile-tree-il): Same here. Also, rely on the fact that an environment *will* be a module -- because (system base compile) guarantees that for us. * module/language/scheme/spec.scm (scheme): In the reader, rely on the environment being a module. Define a #:make-default-environment handler, which returns a beautified module, augmented with a fresh definition for current-reader, so that side effects to current-reader are restricted to the compilation unit. * module/language/tree-il/analyze.scm (report-possibly-unbound-variables): * module/language/tree-il/compile-glil.scm (compile-glil): * module/language/tree-il/optimize.scm (optimize!): The environment will be a module. * module/system/base/language.scm (<language>): New field, `make-default-environment'. Defaults to `make-fresh-user-module'. (default-environment): New accessor, returns a default environment for a language. * module/system/repl/common.scm (repl-compile): Always compile relative to the current module, because a module is always acceptable as an environment. * module/system/base/compile.scm (compile-file, compile-and-load): Both of these have a new keyword argument, #:env. For `compile-file', it defaults to the default environment of the source language, and for `compile-and-load', to the current module. (read-and-compile): If there are no expressions read, pass the joiner its default environment (via `default-environment joint').
114 lines
3.9 KiB
Scheme
114 lines
3.9 KiB
Scheme
;;; Repl common routines
|
||
|
||
;; Copyright (C) 2001, 2008, 2009 Free Software Foundation, Inc.
|
||
|
||
;;; This library is free software; you can redistribute it and/or
|
||
;;; modify it under the terms of the GNU Lesser General Public
|
||
;;; License as published by the Free Software Foundation; either
|
||
;;; version 3 of the License, or (at your option) any later version.
|
||
;;;
|
||
;;; This library is distributed in the hope that it will be useful,
|
||
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
||
;;; Lesser General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU Lesser General Public
|
||
;;; License along with this library; if not, write to the Free Software
|
||
;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
||
|
||
;;; Code:
|
||
|
||
(define-module (system repl common)
|
||
#:use-module (system base syntax)
|
||
#:use-module (system base compile)
|
||
#:use-module (system base language)
|
||
#:use-module (system vm vm)
|
||
#:export (<repl> make-repl repl-vm repl-language repl-options
|
||
repl-tm-stats repl-gc-stats repl-vm-stats
|
||
repl-welcome repl-prompt repl-read repl-compile repl-eval
|
||
repl-parse repl-print repl-option-ref repl-option-set!
|
||
puts ->string user-error))
|
||
|
||
|
||
;;;
|
||
;;; Repl type
|
||
;;;
|
||
|
||
(define-record/keywords <repl> vm language options tm-stats gc-stats vm-stats)
|
||
|
||
(define repl-default-options
|
||
'((trace . #f)
|
||
(interp . #f)))
|
||
|
||
(define %make-repl make-repl)
|
||
(define (make-repl lang)
|
||
(%make-repl #:vm (the-vm)
|
||
#:language (lookup-language lang)
|
||
#:options repl-default-options
|
||
#:tm-stats (times)
|
||
#:gc-stats (gc-stats)
|
||
#:vm-stats (vm-stats (the-vm))))
|
||
|
||
(define (repl-welcome repl)
|
||
(let ((language (repl-language repl)))
|
||
(format #t "~A interpreter ~A on Guile ~A\n"
|
||
(language-title language) (language-version language) (version)))
|
||
(display "Copyright (C) 2001-2008 Free Software Foundation, Inc.\n\n")
|
||
(display "Enter `,help' for help.\n"))
|
||
|
||
(define (repl-prompt repl)
|
||
(format #f "~A@~A> " (language-name (repl-language repl))
|
||
(module-name (current-module))))
|
||
|
||
(define (repl-read repl)
|
||
((language-reader (repl-language repl)) (current-input-port)
|
||
(current-module)))
|
||
|
||
(define (repl-compile repl form . opts)
|
||
(let ((to (lookup-language (cond ((memq #:e opts) 'scheme)
|
||
((memq #:t opts) 'ghil)
|
||
((memq #:c opts) 'glil)
|
||
(else 'objcode))))
|
||
(from (repl-language repl)))
|
||
(compile form #:from from #:to to #:opts opts #:env (current-module))))
|
||
|
||
(define (repl-parse repl form)
|
||
(let ((parser (language-parser (repl-language repl))))
|
||
(if parser (parser form) form)))
|
||
|
||
(define (repl-eval repl form)
|
||
(let ((eval (language-evaluator (repl-language repl))))
|
||
(if (and eval
|
||
(or (null? (language-compilers (repl-language repl)))
|
||
(assq-ref (repl-options repl) 'interp)))
|
||
(eval form (current-module))
|
||
(vm-load (repl-vm repl) (repl-compile repl form '())))))
|
||
|
||
(define (repl-print repl val)
|
||
(if (not (eq? val *unspecified*))
|
||
(begin
|
||
;; The result of an evaluation is representable in scheme, and
|
||
;; should be printed with the generic printer, `write'. The
|
||
;; language-printer is something else: it prints expressions of
|
||
;; a given language, not the result of evaluation.
|
||
(write val)
|
||
(newline))))
|
||
|
||
(define (repl-option-ref repl key)
|
||
(assq-ref (repl-options repl) key))
|
||
|
||
(define (repl-option-set! repl key val)
|
||
(set! (repl-options repl) (assq-set! (repl-options repl) key val)))
|
||
|
||
|
||
;;;
|
||
;;; Utilities
|
||
;;;
|
||
|
||
(define (puts x) (display x) (newline))
|
||
|
||
(define (->string x)
|
||
(object->string x display))
|
||
|
||
(define (user-error msg . args)
|
||
(throw 'user-error #f msg args #f))
|