mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-04-30 20:00:19 +02:00
53e28ed9b2
* gdbinit: Untested attempts to get the stack fondling macros to deal with the new program representation. * libguile/frames.c (scm_vm_frame_arguments, scm_vm_frame_source) (scm_vm_frame_local_ref, scm_vm_frame_local_set_x): SCM_PROGRAM_DATA is a struct scm_objcode*. * libguile/instructions.h: * libguile/instructions.c: Hide the instruction table and the struct scm_instruction structure; all access to instructions now goes through procedures. This is because instructions are no longer in a packed array indexed by opcode. Also, declare a mask that all instructions should fit in. * libguile/objcodes.h: * libguile/objcodes.c: Rewrite so that object code directly maps its arity and length from its bytecode. This makes it unnecessary to keep this information in programs, allowing programs to be simple conses between the code (objcodes) and data (the object table and the closure variables). * libguile/programs.c (scm_make_program): Rework so that make-program takes objcode, an object table, and externals as arguments. It's much clearer this way, and we avoid malloc(). * libguile/stacks.c (is_vm_bootstrap_frame): Update for program/objcode changes. * libguile/vm-engine.c (vm_run): Initialize the jump table on the first run, with the opcodes declared in the instruction sources, and with bad instructions raising an error instead of wandering off into the Unknown. * libguile/vm-engine.h (FETCH_LENGTH): Always represent lengths as 3 bytes. The old code was too error-prone. (NEXT_JUMP): Mask the instruction with SCM_VM_INSTRUCTION_MASK. (NEW_FRAME): Update for program/objcode changes. * libguile/vm-expand.h (VM_DEFINE_FUNCTION, VM_DEFINE_INSTRUCTION) (VM_DEFINE_LOADER): Update so that we explicitly specify opcodes, so that we have a stable bytecode API. * libguile/vm-i-loader.c: Update license to LGPLv2+. Explicitly declare opcodes. (load-integer): Use an int instead of a long as the accumulator; still need to revisit this code at some point, I think. (load-program): Simplify, thankfully!! Just creates the objcode slice and rolls with it. * libguile/vm-i-scheme.c: Number the opcodes explicitly. * libguile/vm-i-system.c: Update license to LGPLv2+. Explicitly declare opcodes. (make-closure): Update for new program API. * libguile/vm.c (vm_make_boot_program): Update for new program/objcode API. Still a bit ugly. (scm_load_compiled_with_vm): Update for new program/objcode API. * module/language/assembly.scm (byte-length): Fix byte-length calculation for loaders, and load-program. (code-pack, code-unpack): Start to move things from (system vm conv) here. (object->code, code->object): More things from conv.scm. * module/language/glil.scm (<glil-program>): Add a new field, closure-level. (make-glil-program, compute-closure-level): Calculate the "closure level" when making a glil program. This is the maximum depth of external binding refs in this closure. (unparse-glil): Fix label serialization. * module/language/glil/compile-assembly.scm (make-meta): Prepend #f for the meta's object table, though maybe in the future we can avoid creating assembly in the first place. (assoc-ref-or-acons, object-index-and-alist): GRRR! Caught again by the different sets of arguments to assoc and assoc-ref! (glil->assembly): Attempt to make the <glil-program> case more readable, and fix the bugs. Sorry I don't know how to comment this change any more than this. (glil->assembly): For <glil-module> serialize the whole key, not just the name. (dump-object): subprogram-code is already a list. Serialize integers as strings, not u8vectors. Fix the order of lists and vectors. * module/language/glil/spec.scm (glil): Switch orders, so we prefer glil -> assembly -> objcode. Actually glil->objcode doesn't work any more, needs to be removed I think. * module/language/objcode/spec.scm (objcode->value): s/objcode->program/make-program/. * module/language/scheme/inline.scm: Add acons inline. * module/system/vm/conv.scm (make-byte-decoder): Skip the first 8 bytes, they are header. Handle subprograms properly. Still needs help though. (decode-length): Lengths are always 3 bytes now. * module/system/vm/disasm.scm: Superficial changes to keep things working. I'd like to fix this better in the future. * module/system/vm/frame.scm (bootstrap-frame?): Fixes for program-bytecode. * module/system/vm/program.scm: Export make-program. It's program-objcode now, no more program-bytecode. * module/system/vm/vm.scm (vm-load): Use make-program. * test-suite/tests/asm-to-bytecode.test: New test, very minimal. * module/system/vm/objcode.scm: Export word-size, byte-order, and write-objcode.
206 lines
6 KiB
Scheme
206 lines
6 KiB
Scheme
;;; GHIL macros
|
|
|
|
;; Copyright (C) 2001 Free Software Foundation, Inc.
|
|
|
|
;; This program is free software; you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation; either version 2, or (at your option)
|
|
;; any later version.
|
|
;;
|
|
;; This program is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
;;
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with this program; see the file COPYING. If not, write to
|
|
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
;; Boston, MA 02111-1307, USA.
|
|
|
|
;;; Code:
|
|
|
|
(define-module (language scheme inline)
|
|
#:use-module (system base syntax)
|
|
#:use-module (language ghil)
|
|
#:use-module (srfi srfi-16)
|
|
#:export (*inline-table* define-inline try-inline try-inline-with-env))
|
|
|
|
(define *inline-table* '())
|
|
|
|
(define-macro (define-inline sym . clauses)
|
|
(define (inline-args args)
|
|
(let lp ((in args) (out '()))
|
|
(cond ((null? in) `(list ,@(reverse out)))
|
|
((symbol? in) `(cons* ,@(reverse out) ,in))
|
|
((pair? (car in))
|
|
(lp (cdr in)
|
|
(cons `(or (try-inline ,(caar in) ,(inline-args (cdar in)))
|
|
(error "what" ',(car in)))
|
|
out)))
|
|
((symbol? (car in))
|
|
;; assume it's locally bound
|
|
(lp (cdr in) (cons (car in) out)))
|
|
((number? (car in))
|
|
(lp (cdr in) (cons `(make-ghil-quote #f #f ,(car in)) out)))
|
|
(else
|
|
(error "what what" (car in))))))
|
|
(define (consequent exp)
|
|
(cond
|
|
((pair? exp)
|
|
`(make-ghil-inline #f #f ',(car exp) ,(inline-args (cdr exp))))
|
|
((symbol? exp)
|
|
;; assume locally bound
|
|
exp)
|
|
((number? exp)
|
|
`(make-ghil-quote #f #f ,exp))
|
|
(else (error "bad consequent yall" exp))))
|
|
`(set! (@ (language scheme inline) *inline-table*)
|
|
(assq-set! (@ (language scheme inline) *inline-table*)
|
|
,sym
|
|
(let ((make-ghil-inline (@ (language ghil) make-ghil-inline))
|
|
(make-ghil-quote (@ (language ghil) make-ghil-quote))
|
|
(try-inline (@ (language scheme inline) try-inline)))
|
|
(case-lambda
|
|
,@(let lp ((in clauses) (out '()))
|
|
(if (null? in)
|
|
(reverse (cons '(else #f) out))
|
|
(lp (cddr in)
|
|
(cons `(,(car in)
|
|
,(consequent (cadr in))) out)))))))))
|
|
|
|
(define (try-inline head-value args)
|
|
(and=> (assq-ref *inline-table* head-value)
|
|
(lambda (proc) (apply proc args))))
|
|
|
|
|
|
(define (try-inline-with-env env loc exp)
|
|
(let ((sym (car exp)))
|
|
(let loop ((e env))
|
|
(record-case e
|
|
((<ghil-toplevel-env> table)
|
|
(let ((mod (current-module)))
|
|
(and (not (assoc-ref table (cons (module-name mod) sym)))
|
|
(module-bound? mod sym)
|
|
(try-inline (module-ref mod sym) (cdr exp)))))
|
|
((<ghil-env> parent table variables)
|
|
(and (not (assq-ref table sym))
|
|
(loop parent)))))))
|
|
|
|
(define-inline eq? (x y)
|
|
(eq? x y))
|
|
|
|
(define-inline eqv? (x y)
|
|
(eqv? x y))
|
|
|
|
(define-inline equal? (x y)
|
|
(equal? x y))
|
|
|
|
(define-inline = (x y)
|
|
(ee? x y))
|
|
|
|
(define-inline < (x y)
|
|
(lt? x y))
|
|
|
|
(define-inline > (x y)
|
|
(gt? x y))
|
|
|
|
(define-inline <= (x y)
|
|
(le? x y))
|
|
|
|
(define-inline >= (x y)
|
|
(ge? x y))
|
|
|
|
(define-inline zero? (x)
|
|
(ee? x 0))
|
|
|
|
(define-inline +
|
|
() 0
|
|
(x) x
|
|
(x y) (add x y)
|
|
(x y . rest) (add x (+ y . rest)))
|
|
|
|
(define-inline *
|
|
() 1
|
|
(x) x
|
|
(x y) (mul x y)
|
|
(x y . rest) (mul x (* y . rest)))
|
|
|
|
(define-inline -
|
|
(x) (sub 0 x)
|
|
(x y) (sub x y)
|
|
(x y . rest) (sub x (+ y . rest)))
|
|
|
|
(define-inline 1-
|
|
(x) (sub x 1))
|
|
|
|
(define-inline /
|
|
(x) (div 1 x)
|
|
(x y) (div x y)
|
|
(x y . rest) (div x (* y . rest)))
|
|
|
|
(define-inline quotient (x y)
|
|
(quo x y))
|
|
|
|
(define-inline remainder (x y)
|
|
(rem x y))
|
|
|
|
(define-inline modulo (x y)
|
|
(mod x y))
|
|
|
|
(define-inline not (x)
|
|
(not x))
|
|
|
|
(define-inline pair? (x)
|
|
(pair? x))
|
|
|
|
(define-inline cons (x y)
|
|
(cons x y))
|
|
|
|
(define-inline car (x) (car x))
|
|
(define-inline cdr (x) (cdr x))
|
|
|
|
(define-inline set-car! (x y) (set-car! x y))
|
|
(define-inline set-cdr! (x y) (set-cdr! x y))
|
|
|
|
(define-inline caar (x) (car (car x)))
|
|
(define-inline cadr (x) (car (cdr x)))
|
|
(define-inline cdar (x) (cdr (car x)))
|
|
(define-inline cddr (x) (cdr (cdr x)))
|
|
(define-inline caaar (x) (car (car (car x))))
|
|
(define-inline caadr (x) (car (car (cdr x))))
|
|
(define-inline cadar (x) (car (cdr (car x))))
|
|
(define-inline caddr (x) (car (cdr (cdr x))))
|
|
(define-inline cdaar (x) (cdr (car (car x))))
|
|
(define-inline cdadr (x) (cdr (car (cdr x))))
|
|
(define-inline cddar (x) (cdr (cdr (car x))))
|
|
(define-inline cdddr (x) (cdr (cdr (cdr x))))
|
|
(define-inline caaaar (x) (car (car (car (car x)))))
|
|
(define-inline caaadr (x) (car (car (car (cdr x)))))
|
|
(define-inline caadar (x) (car (car (cdr (car x)))))
|
|
(define-inline caaddr (x) (car (car (cdr (cdr x)))))
|
|
(define-inline cadaar (x) (car (cdr (car (car x)))))
|
|
(define-inline cadadr (x) (car (cdr (car (cdr x)))))
|
|
(define-inline caddar (x) (car (cdr (cdr (car x)))))
|
|
(define-inline cadddr (x) (car (cdr (cdr (cdr x)))))
|
|
(define-inline cdaaar (x) (cdr (car (car (car x)))))
|
|
(define-inline cdaadr (x) (cdr (car (car (cdr x)))))
|
|
(define-inline cdadar (x) (cdr (car (cdr (car x)))))
|
|
(define-inline cdaddr (x) (cdr (car (cdr (cdr x)))))
|
|
(define-inline cddaar (x) (cdr (cdr (car (car x)))))
|
|
(define-inline cddadr (x) (cdr (cdr (car (cdr x)))))
|
|
(define-inline cdddar (x) (cdr (cdr (cdr (car x)))))
|
|
(define-inline cddddr (x) (cdr (cdr (cdr (cdr x)))))
|
|
|
|
(define-inline null? (x)
|
|
(null? x))
|
|
|
|
(define-inline list? (x)
|
|
(list? x))
|
|
|
|
(define-inline cons*
|
|
(x) x
|
|
(x y) (cons x y)
|
|
(x y . rest) (cons x (cons* y . rest)))
|
|
|
|
(define-inline acons
|
|
(x y z) (cons (cons x y) z))
|