mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-04-30 20:00:19 +02:00
2e65b52f8a
This updates Gnulib to v0.0-4219-g84cdd8b. * m4/gnulib-cache.m4: Add `isinf' and `isnan'. * configure.ac: Remove checks for `floatingpoint.h', `ieeefp.h', and `nan.h'. * libguile/gen-scmconfig.c (main): Remove definitions of `SCM_HAVE_FLOATINGPOINT_H', `SCM_HAVE_IEEEFP_H', and `SCM_HAVE_NAN_H'. * libguile/numbers.c (isnan)[SCO && !HAVE_ISNAN]: Remove. (isinf)[SCO && !HAVE_ISINF]: Remove. (xisinf, xisnan): Remove. Change callers to use `isinf' and `isnan'. (guile_ieee_init): Remove the `defined HAVE_ISINF' and `define HAVE_ISNAN' conditions. * libguile/numbers.h: Remove code conditional on `SCM_HAVE_FLOATINGPOINT_H', `SCM_HAVE_IEEEFP_H', or `SCM_HAVE_NAN_H'.
31 lines
1 KiB
Text
31 lines
1 KiB
Text
# check-math-lib.m4 serial 3
|
|
dnl Copyright (C) 2007, 2009, 2010 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl
|
|
dnl gl_CHECK_MATH_LIB (VARIABLE, EXPRESSION)
|
|
dnl
|
|
dnl Sets the shell VARIABLE according to the libraries needed by EXPRESSION
|
|
dnl to compile and link: to the empty string if no extra libraries are needed,
|
|
dnl to "-lm" if -lm is needed, or to "missing" if it does not compile and
|
|
dnl link either way.
|
|
dnl
|
|
dnl Example: gl_CHECK_MATH_LIB([ROUNDF_LIBM], [x = roundf (x);])
|
|
AC_DEFUN([gl_CHECK_MATH_LIB], [
|
|
save_LIBS=$LIBS
|
|
$1=missing
|
|
for libm in "" "-lm"; do
|
|
LIBS="$save_LIBS $libm"
|
|
AC_LINK_IFELSE([AC_LANG_PROGRAM([[
|
|
#ifndef __NO_MATH_INLINES
|
|
# define __NO_MATH_INLINES 1 /* for glibc */
|
|
#endif
|
|
#include <math.h>
|
|
double x;]],
|
|
[$2])],
|
|
[$1=$libm
|
|
break])
|
|
done
|
|
LIBS=$save_LIBS
|
|
])
|