mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-06 15:40:29 +02:00
ca74e3fae5
* libguile/vm-engine.c (vm_engine): Remove initial VM_HANDLE_INTERRUPTS call; surely our caller already handled interrupts. Add handle-interrupts opcode. * am/bootstrap.am (SOURCES): * module/Makefile.am (SOURCES): Add handle-interrupts.scm. * module/system/vm/assembler.scm (system): * module/language/cps/compile-bytecode.scm (compile-function): (lower-cps): Add handle-interrupts support. * module/language/cps/handle-interrupts.scm: New file.
58 lines
2.1 KiB
Scheme
58 lines
2.1 KiB
Scheme
;;; Continuation-passing style (CPS) intermediate language (IL)
|
|
|
|
;; Copyright (C) 2016 Free Software Foundation, Inc.
|
|
|
|
;;;; This library is free software; you can redistribute it and/or
|
|
;;;; modify it under the terms of the GNU Lesser General Public
|
|
;;;; License as published by the Free Software Foundation; either
|
|
;;;; version 3 of the License, or (at your option) any later version.
|
|
;;;;
|
|
;;;; This library is distributed in the hope that it will be useful,
|
|
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;;;; Lesser General Public License for more details.
|
|
;;;;
|
|
;;;; You should have received a copy of the GNU Lesser General Public
|
|
;;;; License along with this library; if not, write to the Free Software
|
|
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
|
|
|
;;; Commentary:
|
|
;;;
|
|
;;; A pass to add "handle-interrupts" primcalls before calls, loop
|
|
;;; back-edges, and returns.
|
|
;;;
|
|
;;; Code:
|
|
|
|
(define-module (language cps handle-interrupts)
|
|
#:use-module (ice-9 match)
|
|
#:use-module (language cps)
|
|
#:use-module (language cps utils)
|
|
#:use-module (language cps with-cps)
|
|
#:use-module (language cps intmap)
|
|
#:use-module (language cps renumber)
|
|
#:export (add-handle-interrupts))
|
|
|
|
(define (add-handle-interrupts cps)
|
|
(define (visit-cont label cont cps)
|
|
(match cont
|
|
(($ $kargs names vars ($ $continue k src exp))
|
|
(if (or (<= k label)
|
|
(match exp
|
|
(($ $call) #t)
|
|
(($ $callk) #t)
|
|
(($ $values)
|
|
(match (intmap-ref cps k)
|
|
(($ $ktail) #t)
|
|
(_ #f)))
|
|
(_ #f)))
|
|
(with-cps cps
|
|
(letk k* ($kargs () () ($continue k src ,exp)))
|
|
(setk label
|
|
($kargs names vars
|
|
($continue k* src
|
|
($primcall 'handle-interrupts ())))))
|
|
cps))
|
|
(_ cps)))
|
|
(let ((cps (renumber cps)))
|
|
(with-fresh-name-state cps
|
|
(persistent-intmap (intmap-fold visit-cont cps cps)))))
|