mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-11 00:00:49 +02:00
53e28ed9b2
* gdbinit: Untested attempts to get the stack fondling macros to deal with the new program representation. * libguile/frames.c (scm_vm_frame_arguments, scm_vm_frame_source) (scm_vm_frame_local_ref, scm_vm_frame_local_set_x): SCM_PROGRAM_DATA is a struct scm_objcode*. * libguile/instructions.h: * libguile/instructions.c: Hide the instruction table and the struct scm_instruction structure; all access to instructions now goes through procedures. This is because instructions are no longer in a packed array indexed by opcode. Also, declare a mask that all instructions should fit in. * libguile/objcodes.h: * libguile/objcodes.c: Rewrite so that object code directly maps its arity and length from its bytecode. This makes it unnecessary to keep this information in programs, allowing programs to be simple conses between the code (objcodes) and data (the object table and the closure variables). * libguile/programs.c (scm_make_program): Rework so that make-program takes objcode, an object table, and externals as arguments. It's much clearer this way, and we avoid malloc(). * libguile/stacks.c (is_vm_bootstrap_frame): Update for program/objcode changes. * libguile/vm-engine.c (vm_run): Initialize the jump table on the first run, with the opcodes declared in the instruction sources, and with bad instructions raising an error instead of wandering off into the Unknown. * libguile/vm-engine.h (FETCH_LENGTH): Always represent lengths as 3 bytes. The old code was too error-prone. (NEXT_JUMP): Mask the instruction with SCM_VM_INSTRUCTION_MASK. (NEW_FRAME): Update for program/objcode changes. * libguile/vm-expand.h (VM_DEFINE_FUNCTION, VM_DEFINE_INSTRUCTION) (VM_DEFINE_LOADER): Update so that we explicitly specify opcodes, so that we have a stable bytecode API. * libguile/vm-i-loader.c: Update license to LGPLv2+. Explicitly declare opcodes. (load-integer): Use an int instead of a long as the accumulator; still need to revisit this code at some point, I think. (load-program): Simplify, thankfully!! Just creates the objcode slice and rolls with it. * libguile/vm-i-scheme.c: Number the opcodes explicitly. * libguile/vm-i-system.c: Update license to LGPLv2+. Explicitly declare opcodes. (make-closure): Update for new program API. * libguile/vm.c (vm_make_boot_program): Update for new program/objcode API. Still a bit ugly. (scm_load_compiled_with_vm): Update for new program/objcode API. * module/language/assembly.scm (byte-length): Fix byte-length calculation for loaders, and load-program. (code-pack, code-unpack): Start to move things from (system vm conv) here. (object->code, code->object): More things from conv.scm. * module/language/glil.scm (<glil-program>): Add a new field, closure-level. (make-glil-program, compute-closure-level): Calculate the "closure level" when making a glil program. This is the maximum depth of external binding refs in this closure. (unparse-glil): Fix label serialization. * module/language/glil/compile-assembly.scm (make-meta): Prepend #f for the meta's object table, though maybe in the future we can avoid creating assembly in the first place. (assoc-ref-or-acons, object-index-and-alist): GRRR! Caught again by the different sets of arguments to assoc and assoc-ref! (glil->assembly): Attempt to make the <glil-program> case more readable, and fix the bugs. Sorry I don't know how to comment this change any more than this. (glil->assembly): For <glil-module> serialize the whole key, not just the name. (dump-object): subprogram-code is already a list. Serialize integers as strings, not u8vectors. Fix the order of lists and vectors. * module/language/glil/spec.scm (glil): Switch orders, so we prefer glil -> assembly -> objcode. Actually glil->objcode doesn't work any more, needs to be removed I think. * module/language/objcode/spec.scm (objcode->value): s/objcode->program/make-program/. * module/language/scheme/inline.scm: Add acons inline. * module/system/vm/conv.scm (make-byte-decoder): Skip the first 8 bytes, they are header. Handle subprograms properly. Still needs help though. (decode-length): Lengths are always 3 bytes now. * module/system/vm/disasm.scm: Superficial changes to keep things working. I'd like to fix this better in the future. * module/system/vm/frame.scm (bootstrap-frame?): Fixes for program-bytecode. * module/system/vm/program.scm: Export make-program. It's program-objcode now, no more program-bytecode. * module/system/vm/vm.scm (vm-load): Use make-program. * test-suite/tests/asm-to-bytecode.test: New test, very minimal. * module/system/vm/objcode.scm: Export word-size, byte-order, and write-objcode.
167 lines
5.6 KiB
Scheme
167 lines
5.6 KiB
Scheme
;;; Guile Low Intermediate Language
|
||
|
||
;; Copyright (C) 2001 Free Software Foundation, Inc.
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation; either version 2, or (at your option)
|
||
;; any later version.
|
||
;;
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
;;
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program; see the file COPYING. If not, write to
|
||
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
||
;; Boston, MA 02111-1307, USA.
|
||
|
||
;;; Code:
|
||
|
||
(define-module (language glil)
|
||
#:use-module (system base syntax)
|
||
#:use-module (system base pmatch)
|
||
#:use-module ((srfi srfi-1) #:select (fold))
|
||
#:export
|
||
(<glil-program> make-glil-program glil-program?
|
||
glil-program-nargs glil-program-nrest glil-program-nlocs glil-program-nexts
|
||
glil-program-meta glil-program-body glil-program-closure-level
|
||
|
||
<glil-bind> make-glil-bind glil-bind?
|
||
glil-bind-vars
|
||
|
||
<glil-mv-bind> make-glil-mv-bind glil-mv-bind?
|
||
glil-mv-bind-vars glil-mv-bind-rest
|
||
|
||
<glil-unbind> make-glil-unbind glil-unbind?
|
||
|
||
<glil-source> make-glil-source glil-source?
|
||
glil-source-loc
|
||
|
||
<glil-void> make-glil-void glil-void?
|
||
|
||
<glil-const> make-glil-const glil-const?
|
||
glil-const-obj
|
||
|
||
<glil-argument> make-glil-argument glil-argument?
|
||
glil-argument-op glil-argument-index
|
||
|
||
<glil-local> make-glil-local glil-local?
|
||
glil-local-op glil-local-index
|
||
|
||
<glil-external> make-glil-external glil-external?
|
||
glil-external-op glil-external-depth glil-external-index
|
||
|
||
<glil-toplevel> make-glil-toplevel glil-toplevel?
|
||
glil-toplevel-op glil-toplevel-name
|
||
|
||
<glil-module> make-glil-module glil-module?
|
||
glil-module-op glil-module-mod glil-module-name glil-module-public?
|
||
|
||
<glil-label> make-glil-label glil-label?
|
||
glil-label-label
|
||
|
||
<glil-branch> make-glil-branch glil-branch?
|
||
glil-branch-inst glil-branch-label
|
||
|
||
<glil-call> make-glil-call glil-call?
|
||
glil-call-inst glil-call-nargs
|
||
|
||
<glil-mv-call> make-glil-mv-call glil-mv-call?
|
||
glil-mv-call-nargs glil-mv-call-ra
|
||
|
||
parse-glil unparse-glil))
|
||
|
||
(define (print-glil x port)
|
||
(format port "#<glil ~s>" (unparse-glil x)))
|
||
|
||
(define-type (<glil> #:printer print-glil)
|
||
;; Meta operations
|
||
(<glil-program> nargs nrest nlocs nexts meta body (closure-level #f))
|
||
(<glil-bind> vars)
|
||
(<glil-mv-bind> vars rest)
|
||
(<glil-unbind>)
|
||
(<glil-source> loc)
|
||
;; Objects
|
||
(<glil-void>)
|
||
(<glil-const> obj)
|
||
;; Variables
|
||
(<glil-argument> op index)
|
||
(<glil-local> op index)
|
||
(<glil-external> op depth index)
|
||
(<glil-toplevel> op name)
|
||
(<glil-module> op mod name public?)
|
||
;; Controls
|
||
(<glil-label> label)
|
||
(<glil-branch> inst label)
|
||
(<glil-call> inst nargs)
|
||
(<glil-mv-call> nargs ra))
|
||
|
||
(define (compute-closure-level body)
|
||
(fold (lambda (x ret)
|
||
(record-case x
|
||
((<glil-program> closure-level) (max ret closure-level))
|
||
((<glil-external> depth) (max ret depth))
|
||
(else ret)))
|
||
0 body))
|
||
|
||
(define %make-glil-program make-glil-program)
|
||
(define (make-glil-program . args)
|
||
(let ((prog (apply %make-glil-program args)))
|
||
(if (not (glil-program-closure-level prog))
|
||
(set! (glil-program-closure-level prog)
|
||
(compute-closure-level (glil-program-body prog))))
|
||
prog))
|
||
|
||
|
||
(define (parse-glil x)
|
||
(pmatch x
|
||
((program ,nargs ,nrest ,nlocs ,nexts ,meta . ,body)
|
||
(make-glil-program nargs nrest nlocs nexts meta (map parse-glil body)))
|
||
((bind . ,vars) (make-glil-bind vars))
|
||
((mv-bind ,vars . ,rest) (make-glil-mv-bind vars (map parse-glil rest)))
|
||
((unbind) (make-glil-unbind))
|
||
((source ,loc) (make-glil-source loc))
|
||
((void) (make-glil-void))
|
||
((const ,obj) (make-glil-const obj))
|
||
((argument ,op ,index) (make-glil-argument op index))
|
||
((local ,op ,index) (make-glil-local op index))
|
||
((external ,op ,depth ,index) (make-glil-external op depth index))
|
||
((toplevel ,op ,name) (make-glil-toplevel op name))
|
||
((module public ,op ,mod ,name) (make-glil-module op mod name #t))
|
||
((module private ,op ,mod ,name) (make-glil-module op mod name #f))
|
||
((label ,label) (make-label ,label))
|
||
((branch ,inst ,label) (make-glil-branch inst label))
|
||
((call ,inst ,nargs) (make-glil-call inst nargs))
|
||
((mv-call ,nargs ,ra) (make-glil-mv-call nargs ra))
|
||
(else (error "invalid glil" x))))
|
||
|
||
(define (unparse-glil glil)
|
||
(record-case glil
|
||
;; meta
|
||
((<glil-program> nargs nrest nlocs nexts meta body)
|
||
`(program ,nargs ,nrest ,nlocs ,nexts ,meta ,@(map unparse-glil body)))
|
||
((<glil-bind> vars) `(bind ,@vars))
|
||
((<glil-mv-bind> vars rest) `(mv-bind ,vars ,@rest))
|
||
((<glil-unbind>) `(unbind))
|
||
((<glil-source> loc) `(source ,loc))
|
||
;; constants
|
||
((<glil-void>) `(void))
|
||
((<glil-const> obj) `(const ,obj))
|
||
;; variables
|
||
((<glil-argument> op index)
|
||
`(argument ,op ,index))
|
||
((<glil-local> op index)
|
||
`(local ,op ,index))
|
||
((<glil-external> op depth index)
|
||
`(external ,op ,depth ,index))
|
||
((<glil-toplevel> op name)
|
||
`(toplevel ,op ,name))
|
||
((<glil-module> op mod name public?)
|
||
`(module ,(if public? 'public 'private) ,op ,mod ,name))
|
||
;; controls
|
||
((<glil-label> label) `(label ,label))
|
||
((<glil-branch> inst label) `(branch ,inst ,label))
|
||
((<glil-call> inst nargs) `(call ,inst ,nargs))
|
||
((<glil-mv-call> nargs ra) `(mv-call ,nargs ,(unparse-glil ra)))))
|