mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-08 22:12:26 +02:00
49114fd43d
This updates Gnulib to v0.0-4889-ge375fe3. * m4/gnulib-cache.m4: Add `accept', `bind', `close', `connect', `getpeername', `getsockname', `getsockopt', `listen', `malloc', `malloca', `recv', `recvfrom', `send', `sendto', `setsockopt', `shutdown', `socket', and `sockets', requested by Jan Nieuwenhuizen <janneke-list@xs4all.nl> for cross-MinGW32 builds. Add `trunc', requested by Mark H Weaver <mhw@netris.org>.
41 lines
1.2 KiB
Text
41 lines
1.2 KiB
Text
# putenv.m4 serial 17
|
|
dnl Copyright (C) 2002-2011 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Jim Meyering.
|
|
dnl
|
|
dnl Check whether putenv ("FOO") removes FOO from the environment.
|
|
dnl The putenv in libc on at least SunOS 4.1.4 does *not* do that.
|
|
|
|
AC_DEFUN([gl_FUNC_PUTENV],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
AC_CACHE_CHECK([for putenv compatible with GNU and SVID],
|
|
[gl_cv_func_svid_putenv],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],[[
|
|
/* Put it in env. */
|
|
if (putenv ("CONFTEST_putenv=val"))
|
|
return 1;
|
|
|
|
/* Try to remove it. */
|
|
if (putenv ("CONFTEST_putenv"))
|
|
return 2;
|
|
|
|
/* Make sure it was deleted. */
|
|
if (getenv ("CONFTEST_putenv") != 0)
|
|
return 3;
|
|
|
|
return 0;
|
|
]])],
|
|
gl_cv_func_svid_putenv=yes,
|
|
gl_cv_func_svid_putenv=no,
|
|
dnl When crosscompiling, assume putenv is broken.
|
|
gl_cv_func_svid_putenv=no)
|
|
])
|
|
if test $gl_cv_func_svid_putenv = no; then
|
|
REPLACE_PUTENV=1
|
|
AC_LIBOBJ([putenv])
|
|
fi
|
|
])
|