mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-09 07:00:23 +02:00
49114fd43d
This updates Gnulib to v0.0-4889-ge375fe3. * m4/gnulib-cache.m4: Add `accept', `bind', `close', `connect', `getpeername', `getsockname', `getsockopt', `listen', `malloc', `malloca', `recv', `recvfrom', `send', `sendto', `setsockopt', `shutdown', `socket', and `sockets', requested by Jan Nieuwenhuizen <janneke-list@xs4all.nl> for cross-MinGW32 builds. Add `trunc', requested by Mark H Weaver <mhw@netris.org>.
44 lines
1.3 KiB
Text
44 lines
1.3 KiB
Text
# inet_pton.m4 serial 11
|
|
dnl Copyright (C) 2006, 2008-2011 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_INET_PTON],
|
|
[
|
|
dnl Persuade Solaris <arpa/inet.h> to declare inet_pton.
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
gl_REPLACE_ARPA_INET_H
|
|
|
|
dnl Most platforms that provide inet_pton define it in libc.
|
|
dnl Solaris 8..10 provide inet_pton in libnsl instead.
|
|
gl_save_LIBS=$LIBS
|
|
AC_SEARCH_LIBS([inet_pton], [nsl], [],
|
|
[AC_REPLACE_FUNCS([inet_pton])])
|
|
LIBS=$gl_save_LIBS
|
|
INET_PTON_LIB=
|
|
if test "$ac_cv_search_inet_pton" != "no" &&
|
|
test "$ac_cv_search_inet_pton" != "none required"; then
|
|
INET_PTON_LIB="$ac_cv_search_inet_pton"
|
|
fi
|
|
AC_SUBST([INET_PTON_LIB])
|
|
|
|
gl_PREREQ_INET_PTON
|
|
])
|
|
|
|
# Prerequisites of lib/inet_pton.c.
|
|
AC_DEFUN([gl_PREREQ_INET_PTON], [
|
|
AC_CHECK_HEADERS_ONCE([netdb.h])
|
|
AC_CHECK_DECLS([inet_pton],,,
|
|
[#include <arpa/inet.h>
|
|
#if HAVE_NETDB_H
|
|
# include <netdb.h>
|
|
#endif
|
|
])
|
|
if test $ac_cv_have_decl_inet_pton = no; then
|
|
HAVE_DECL_INET_PTON=0
|
|
fi
|
|
AC_REQUIRE([gl_SOCKET_FAMILIES])
|
|
AC_REQUIRE([AC_C_RESTRICT])
|
|
])
|