mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-08 21:42:28 +02:00
49114fd43d
This updates Gnulib to v0.0-4889-ge375fe3. * m4/gnulib-cache.m4: Add `accept', `bind', `close', `connect', `getpeername', `getsockname', `getsockopt', `listen', `malloc', `malloca', `recv', `recvfrom', `send', `sendto', `setsockopt', `shutdown', `socket', and `sockets', requested by Jan Nieuwenhuizen <janneke-list@xs4all.nl> for cross-MinGW32 builds. Add `trunc', requested by Mark H Weaver <mhw@netris.org>.
62 lines
1.9 KiB
Text
62 lines
1.9 KiB
Text
dnl Reentrant time functions: localtime_r, gmtime_r.
|
|
|
|
dnl Copyright (C) 2003, 2006-2011 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Written by Paul Eggert.
|
|
|
|
AC_DEFUN([gl_TIME_R],
|
|
[
|
|
dnl Persuade glibc and Solaris <time.h> to declare localtime_r.
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
|
|
AC_REQUIRE([AC_C_RESTRICT])
|
|
|
|
dnl Some systems don't declare localtime_r() and gmtime_r() if _REENTRANT is
|
|
dnl not defined.
|
|
AC_CHECK_DECLS_ONCE([localtime_r])
|
|
if test $ac_cv_have_decl_localtime_r = no; then
|
|
HAVE_DECL_LOCALTIME_R=0
|
|
fi
|
|
|
|
AC_CHECK_FUNCS_ONCE([localtime_r])
|
|
if test $ac_cv_func_localtime_r = yes; then
|
|
HAVE_LOCALTIME_R=1
|
|
AC_CACHE_CHECK([whether localtime_r is compatible with its POSIX signature],
|
|
[gl_cv_time_r_posix],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <time.h>]],
|
|
[[/* We don't need to append 'restrict's to the argument types,
|
|
even though the POSIX signature has the 'restrict's,
|
|
since C99 says they can't affect type compatibility. */
|
|
struct tm * (*ptr) (time_t const *, struct tm *) = localtime_r;
|
|
if (ptr) return 0;
|
|
/* Check the return type is a pointer.
|
|
On HP-UX 10 it is 'int'. */
|
|
*localtime_r (0, 0);]])
|
|
],
|
|
[gl_cv_time_r_posix=yes],
|
|
[gl_cv_time_r_posix=no])
|
|
])
|
|
if test $gl_cv_time_r_posix = yes; then
|
|
REPLACE_LOCALTIME_R=0
|
|
else
|
|
REPLACE_LOCALTIME_R=1
|
|
fi
|
|
else
|
|
HAVE_LOCALTIME_R=0
|
|
fi
|
|
if test $HAVE_LOCALTIME_R = 0 || test $REPLACE_LOCALTIME_R = 1; then
|
|
AC_LIBOBJ([time_r])
|
|
gl_PREREQ_TIME_R
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/time_r.c.
|
|
AC_DEFUN([gl_PREREQ_TIME_R], [
|
|
:
|
|
])
|