mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-06-07 04:30:18 +02:00
56164a5a6c
* libguile/objcodes.h (struct scm_objcode): Remove nargs, nrest, and nlocs, as they are no longer needed. Also obviates the need for a padding word. * libguile/procs.c (scm_thunk_p): Use scm_i_program_arity for programs. * libguile/procprop.c (scm_i_procedure_arity): Use scm_i_program_arity for programs. (scm_procedure_properties, scm_set_procedure_properties_x) (scm_procedure_property, scm_set_procedure_property_x): Rework so that non-closure properties are stored directly in a weak hash, instead of needing a weak hash of "stand-in" closures to hold the properties. Fix docstrings also. * libguile/root.h (scm_stand_in_procs): Remove from the scm_sys_protects set. Actually with libGC, we should be able to store the elements of scm_sys_protects directly as global variables. * libguile/gc.c (scm_init_storage): Remove scm_stand_in_procs initialization. * libguile/programs.c (scm_i_program_arity): New private accessor, tries to determine the "minimum arity" of a program. * libguile/vm.c (really_make_boot_program): Adapt to changes in struct scm_objcode. * module/language/assembly.scm (*program-header-len*, byte-length): * module/language/assembly/compile-bytecode.scm (write-bytecode): * module/language/assembly/decompile-bytecode.scm (decode-load-program): * module/language/assembly/disassemble.scm (disassemble-load-program): Adapt to changes in objcode. * module/system/xref.scm (program-callee-rev-vars): Adapt to changes in assembly. * module/language/glil.scm: Remove nargs, nrest, and nlocs from glil-program. * module/language/glil/compile-assembly.scm (make-meta, glil->assembly): * module/language/glil/decompile-assembly.scm (decompile-toplevel): (decompile-load-program): Adapt to changes in GLIL and assembly. * module/language/tree-il/compile-glil.scm (flatten-lambda): Adapt to changes in GLIL. * test-suite/tests/asm-to-bytecode.test: Adapt to assembly and bytecode changes. * test-suite/tests/tree-il.test: Adapt to GLIL changes.
128 lines
5.1 KiB
Scheme
128 lines
5.1 KiB
Scheme
;;; Guile VM code converters
|
|
|
|
;; Copyright (C) 2001, 2009 Free Software Foundation, Inc.
|
|
|
|
;;;; This library is free software; you can redistribute it and/or
|
|
;;;; modify it under the terms of the GNU Lesser General Public
|
|
;;;; License as published by the Free Software Foundation; either
|
|
;;;; version 3 of the License, or (at your option) any later version.
|
|
;;;;
|
|
;;;; This library is distributed in the hope that it will be useful,
|
|
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;;;; Lesser General Public License for more details.
|
|
;;;;
|
|
;;;; You should have received a copy of the GNU Lesser General Public
|
|
;;;; License along with this library; if not, write to the Free Software
|
|
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
|
|
|
;;; Code:
|
|
|
|
(define-module (language assembly decompile-bytecode)
|
|
#:use-module (system vm instruction)
|
|
#:use-module (system base pmatch)
|
|
#:use-module (srfi srfi-4)
|
|
#:use-module (rnrs bytevector)
|
|
#:use-module (language assembly)
|
|
#:use-module ((system vm objcode) #:select (byte-order))
|
|
#:export (decompile-bytecode))
|
|
|
|
(define (decompile-bytecode x env opts)
|
|
(let ((i 0) (size (u8vector-length x)))
|
|
(define (pop)
|
|
(let ((b (cond ((< i size) (u8vector-ref x i))
|
|
((= i size) #f)
|
|
(else (error "tried to decode too many bytes")))))
|
|
(if b (set! i (1+ i)))
|
|
b))
|
|
(let ((ret (decode-load-program pop)))
|
|
(if (= i size)
|
|
(values ret env)
|
|
(error "bad bytecode: only decoded ~a out of ~a bytes" i size)))))
|
|
|
|
(define (br-instruction? x)
|
|
(memq x '(br br-if br-if-not br-if-eq br-if-not-eq br-if-null br-if-not-null)))
|
|
|
|
(define (bytes->s24 a b c)
|
|
(let ((x (+ (ash a 16) (ash b 8) c)))
|
|
(if (zero? (logand (ash 1 23) x))
|
|
x
|
|
(- x (ash 1 24)))))
|
|
|
|
;; FIXME: this is a little-endian disassembly!!!
|
|
(define (decode-load-program pop)
|
|
(let* ((a (pop)) (b (pop)) (c (pop)) (d (pop))
|
|
(e (pop)) (f (pop)) (g (pop)) (h (pop))
|
|
(len (+ a (ash b 8) (ash c 16) (ash d 24)))
|
|
(metalen (+ e (ash f 8) (ash g 16) (ash h 24)))
|
|
(labels '())
|
|
(i 0))
|
|
(define (ensure-label rel1 rel2 rel3)
|
|
(let ((where (+ i (bytes->s24 rel1 rel2 rel3))))
|
|
(or (assv-ref labels where)
|
|
(begin
|
|
(let ((l (gensym ":L")))
|
|
(set! labels (acons where l labels))
|
|
l)))))
|
|
(define (sub-pop) ;; ...records. ha. ha.
|
|
(let ((b (cond ((< i len) (pop))
|
|
((= i len) #f)
|
|
(else (error "tried to decode too many bytes")))))
|
|
(if b (set! i (1+ i)))
|
|
b))
|
|
(let lp ((out '()))
|
|
(cond ((> i len)
|
|
(error "error decoding program -- read too many bytes" out))
|
|
((= i len)
|
|
`(load-program ,(map (lambda (x) (cons (cdr x) (car x)))
|
|
(reverse labels))
|
|
,len
|
|
,(if (zero? metalen) #f (decode-load-program pop))
|
|
,@(reverse! out)))
|
|
(else
|
|
(let ((exp (decode-bytecode sub-pop)))
|
|
(pmatch exp
|
|
((,br ,rel1 ,rel2 ,rel3) (guard (br-instruction? br))
|
|
(lp (cons `(,br ,(ensure-label rel1 rel2 rel3)) out)))
|
|
((mv-call ,n ,rel1 ,rel2 ,rel3)
|
|
(lp (cons `(mv-call ,n ,(ensure-label rel1 rel2 rel3)) out)))
|
|
(else
|
|
(lp (cons exp out))))))))))
|
|
|
|
(define (decode-bytecode pop)
|
|
(and=> (pop)
|
|
(lambda (opcode)
|
|
(let ((inst (opcode->instruction opcode)))
|
|
(cond
|
|
((eq? inst 'load-program)
|
|
(decode-load-program pop))
|
|
|
|
((< (instruction-length inst) 0)
|
|
;; the negative length indicates a variable length
|
|
;; instruction
|
|
(let* ((make-sequence
|
|
(if (or (memq inst '(load-array load-wide-string)))
|
|
make-bytevector
|
|
make-string))
|
|
(sequence-set!
|
|
(if (or (memq inst '(load-array load-wide-string)))
|
|
bytevector-u8-set!
|
|
(lambda (str pos value)
|
|
(string-set! str pos (integer->char value)))))
|
|
(len (let* ((a (pop)) (b (pop)) (c (pop)))
|
|
(+ (ash a 16) (ash b 8) c)))
|
|
(seq (make-sequence len)))
|
|
(let lp ((i 0))
|
|
(if (= i len)
|
|
`(,inst ,(if (eq? inst 'load-wide-string)
|
|
(utf32->string seq)
|
|
seq))
|
|
(begin
|
|
(sequence-set! seq i (pop))
|
|
(lp (1+ i)))))))
|
|
(else
|
|
;; fixed length
|
|
(let lp ((n (instruction-length inst)) (out (list inst)))
|
|
(if (zero? n)
|
|
(reverse! out)
|
|
(lp (1- n) (cons (pop) out))))))))))
|