mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-06-09 13:30:26 +02:00
96589bd303
* module/ice-9/boot-9.scm(symbol-property, set-symbol-property!) (symbol-property-remove!): Remove. * module/ice-9/boot-9.scm (make-record-type): Name must be symbol. (record-constructor): Alias record-type-constructor. (make-module): Require size to be zero. Should fix this with keyword args :/ (try-load-module): Inline definition of try-module-autoload. Remove try-module-autoload binding. (make-soft-port): Add deprecation warning, so we can remove it eventually. * module/ice-9/save-stack.scm: Remove deprecation comment. * module/ice-9/top-repl.scm: * module/ice-9/threads.scm: Export instead of replace bindings. * module/language/bytecode.scm: Remove instruction-arity et al. * module/language/tree-il/analyze.scm: Remove deprecated unbound-variable-analysis and macro-use-before-definition-analysis. * module/rnrs.scm: Fix syntax-case export now that module and value namespaces are separate. * module/system/base/language.scm (invalidate-compilation-cache!): Remove. * module/system/base/language.scm (*current-language*): Remove.
74 lines
2.6 KiB
Scheme
74 lines
2.6 KiB
Scheme
;;; -*- mode: scheme; coding: utf-8; -*-
|
|
|
|
;;;; Copyright (C) 1995-2011,2013,2019,2025 Free Software Foundation, Inc.
|
|
;;;;
|
|
;;;; This library is free software; you can redistribute it and/or
|
|
;;;; modify it under the terms of the GNU Lesser General Public
|
|
;;;; License as published by the Free Software Foundation; either
|
|
;;;; version 3 of the License, or (at your option) any later version.
|
|
;;;;
|
|
;;;; This library is distributed in the hope that it will be useful,
|
|
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;;;; Lesser General Public License for more details.
|
|
;;;;
|
|
;;;; You should have received a copy of the GNU Lesser General Public
|
|
;;;; License along with this library; if not, write to the Free Software
|
|
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
|
;;;;
|
|
|
|
(define-module (ice-9 top-repl)
|
|
#:use-module (ice-9 top-repl)
|
|
#:use-module ((system repl repl) #:select (start-repl))
|
|
#:export (top-repl))
|
|
|
|
(define call-with-sigint
|
|
(if (not (provided? 'posix))
|
|
(lambda (thunk) (thunk))
|
|
(lambda (thunk)
|
|
(let ((handler #f))
|
|
(dynamic-wind
|
|
(lambda ()
|
|
(set! handler
|
|
(sigaction SIGINT
|
|
(lambda (sig)
|
|
(scm-error 'signal #f "User interrupt" '()
|
|
(list sig))))))
|
|
thunk
|
|
(lambda ()
|
|
(if handler
|
|
;; restore Scheme handler, SIG_IGN or SIG_DFL.
|
|
(sigaction SIGINT (car handler) (cdr handler))
|
|
;; restore original C handler.
|
|
(sigaction SIGINT #f))))))))
|
|
|
|
(define (top-repl)
|
|
(let ((guile-user-module (resolve-module '(guile-user))))
|
|
|
|
;; Use some convenient modules (in reverse order)
|
|
|
|
(set-current-module guile-user-module)
|
|
(process-use-modules
|
|
(append
|
|
'(((ice-9 session)))
|
|
(if (provided? 'regex)
|
|
'(((ice-9 regex)))
|
|
'())
|
|
(if (provided? 'threads)
|
|
'(((ice-9 threads)))
|
|
'())))
|
|
|
|
(call-with-sigint
|
|
(lambda ()
|
|
(and (defined? 'setlocale)
|
|
(catch 'system-error
|
|
(lambda ()
|
|
(setlocale LC_ALL ""))
|
|
(lambda (key subr fmt args errno)
|
|
(format (current-error-port)
|
|
"warning: failed to install locale: ~a~%"
|
|
(strerror (car errno))))))
|
|
|
|
(let ((status (start-repl (current-language))))
|
|
(run-hook exit-hook)
|
|
status)))))
|