mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-19 19:20:23 +02:00
49114fd43d
This updates Gnulib to v0.0-4889-ge375fe3. * m4/gnulib-cache.m4: Add `accept', `bind', `close', `connect', `getpeername', `getsockname', `getsockopt', `listen', `malloc', `malloca', `recv', `recvfrom', `send', `sendto', `setsockopt', `shutdown', `socket', and `sockets', requested by Jan Nieuwenhuizen <janneke-list@xs4all.nl> for cross-MinGW32 builds. Add `trunc', requested by Mark H Weaver <mhw@netris.org>.
61 lines
1.9 KiB
Text
61 lines
1.9 KiB
Text
# sockpfaf.m4 serial 7
|
|
dnl Copyright (C) 2004, 2006, 2009-2011 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Test for some common socket protocol families (PF_INET, PF_INET6, ...)
|
|
dnl and some common address families (AF_INET, AF_INET6, ...).
|
|
dnl This test assumes that a system supports an address family if and only if
|
|
dnl it supports the corresponding protocol family.
|
|
|
|
dnl From Bruno Haible.
|
|
|
|
AC_DEFUN([gl_SOCKET_FAMILIES],
|
|
[
|
|
AC_REQUIRE([gl_HEADER_SYS_SOCKET])
|
|
AC_CHECK_HEADERS_ONCE([netinet/in.h])
|
|
|
|
AC_MSG_CHECKING([for IPv4 sockets])
|
|
AC_CACHE_VAL([gl_cv_socket_ipv4],
|
|
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
|
|
#ifdef HAVE_SYS_SOCKET_H
|
|
#include <sys/socket.h>
|
|
#endif
|
|
#ifdef HAVE_NETINET_IN_H
|
|
#include <netinet/in.h>
|
|
#endif
|
|
#ifdef HAVE_WINSOCK2_H
|
|
#include <winsock2.h>
|
|
#endif]],
|
|
[[int x = AF_INET; struct in_addr y; struct sockaddr_in z;
|
|
if (&x && &y && &z) return 0;]])],
|
|
gl_cv_socket_ipv4=yes, gl_cv_socket_ipv4=no)])
|
|
AC_MSG_RESULT([$gl_cv_socket_ipv4])
|
|
if test $gl_cv_socket_ipv4 = yes; then
|
|
AC_DEFINE([HAVE_IPV4], [1], [Define to 1 if <sys/socket.h> defines AF_INET.])
|
|
fi
|
|
|
|
AC_MSG_CHECKING([for IPv6 sockets])
|
|
AC_CACHE_VAL([gl_cv_socket_ipv6],
|
|
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
|
|
#ifdef HAVE_SYS_SOCKET_H
|
|
#include <sys/socket.h>
|
|
#endif
|
|
#ifdef HAVE_NETINET_IN_H
|
|
#include <netinet/in.h>
|
|
#endif
|
|
#ifdef HAVE_WINSOCK2_H
|
|
#include <winsock2.h>
|
|
#endif
|
|
#ifdef HAVE_WS2TCPIP_H
|
|
#include <ws2tcpip.h>
|
|
#endif]],
|
|
[[int x = AF_INET6; struct in6_addr y; struct sockaddr_in6 z;
|
|
if (&x && &y && &z) return 0;]])],
|
|
gl_cv_socket_ipv6=yes, gl_cv_socket_ipv6=no)])
|
|
AC_MSG_RESULT([$gl_cv_socket_ipv6])
|
|
if test $gl_cv_socket_ipv6 = yes; then
|
|
AC_DEFINE([HAVE_IPV6], [1], [Define to 1 if <sys/socket.h> defines AF_INET6.])
|
|
fi
|
|
])
|