mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-04-30 11:50:28 +02:00
b0b180d522
* module/system/base/language.scm (<language>): Rework so that instead of hardcoding passes in the language, we define compilers that translate from one language to another. Add `parser' to the language fields, a bit of a hack but useful for languages with s-expression external representations but with record internal representations. (define-language, *compilation-cache*, invalidate-compilation-cache!) (compute-compilation-order, lookup-compilation-order): Add an algorithm that does a depth-first search for a translation path from a source language to a target language, caching the result in a lookup table. * module/language/scheme/spec.scm: * module/language/ghil/spec.scm: Update to the new language format. * module/language/glil/spec.scm: Add a language specification for GLIL, with a compiler to objcode. Also there are parsers and printers, for repl usage, but for some reason this doesn't work yet. * module/language/objcode/spec.scm: Define a language specification for object code. There is some sleight of hand here, in the "compiler" to values; but there is method behind the madness, because this way we higher levels can pass environments (a module + externals pair) to objcode->program. * module/language/value/spec.scm: Define a language specification for values. There is something intellectually dishonest about this, but it does serve its purpose as a foundation for the language hierarchy. * configure.in: * module/language/Makefile.am * module/language/ghil/Makefile.am * module/language/glil/Makefile.am * module/language/objcode/Makefile.am * module/language/value/Makefile.am: Autotomfoolery for the ghil, glil, objcode, and value languages. * module/language/scheme/translate.scm (translate): Import the bits that understand `compile-time-environment' here, and pass on the relevant portions of the environment to the next compiler pass. * module/system/base/compile.scm (current-language): New procedure, refs the current language fluid, or lazily sets it to scheme. (call-once, call-with-output-file/atomic): Refactor these bits to use with-throw-handler. No functional change. (compile-file, compile-and-load, compile-passes, compile-fold) (compile): Refactor the public interface of the compiler to be generic and simple. Uses `lookup-compilation-order' to find a path from the source language to the target language. * module/system/base/syntax.scm (define-type): Adapt to changes in define-record. (define-record): Instead of expecting all slots in the first form, expect them in the body, and let the first form hold the options. * module/system/il/compile.scm (compile): Adapt to the compilation pass API (three in and two out). * module/system/il/ghil.scm (<ghil-var>, <ghil-env>) (<ghil-toplevel-env>): Adapt to define-record changes. * module/system/il/glil.scm (<glil-vars>): Adapt to define-record changes. (<glil>, print-glil): Add a GLIL record printer that uses unparse. (parse-glil, unparse-glil): Update unparse (formerly known as pprint), and write a parse function. * module/system/repl/common.scm (<repl>): Adapt to define-record changes. (repl-parse): New function, parses the read form using the current language. Something of a hack. (repl-compile): Adapt to changes in `compile'. (repl-eval): Fix up the does-the-language-have-a-compiler check for changes in <language>. * module/system/repl/repl.scm (start-repl): Parse the form before eval. * module/system/repl/command.scm (describe): Parse. (compile): Be more generic. (compile-file): Adapt to changes in compile-file. (disassemble, time, profile, trace): Parse. * module/system/vm/debug.scm: * module/system/vm/assemble.scm: Adapt to define-record changes. * module/language/scheme/translate.scm (receive): Fix an important bug that gave `receive' letrec semantics instead of let semantics. Whoops!
113 lines
3.7 KiB
Scheme
113 lines
3.7 KiB
Scheme
;;; Repl common routines
|
||
|
||
;; Copyright (C) 2001 Free Software Foundation, Inc.
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation; either version 2, or (at your option)
|
||
;; any later version.
|
||
;;
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
;;
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program; see the file COPYING. If not, write to
|
||
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
||
;; Boston, MA 02111-1307, USA.
|
||
|
||
;;; Code:
|
||
|
||
(define-module (system repl common)
|
||
#:use-syntax (system base syntax)
|
||
#:use-module (system base compile)
|
||
#:use-module (system base language)
|
||
#:use-module (system vm vm)
|
||
#:export (<repl> make-repl repl-vm repl-language repl-options
|
||
repl-tm-stats repl-gc-stats repl-vm-stats
|
||
repl-welcome repl-prompt repl-read repl-compile repl-eval
|
||
repl-parse repl-print repl-option-ref repl-option-set!
|
||
puts ->string user-error))
|
||
|
||
|
||
;;;
|
||
;;; Repl type
|
||
;;;
|
||
|
||
(define-record <repl> vm language options tm-stats gc-stats vm-stats)
|
||
|
||
(define repl-default-options
|
||
'((trace . #f)
|
||
(interp . #f)))
|
||
|
||
(define %make-repl make-repl)
|
||
(define (make-repl lang)
|
||
(%make-repl #:vm (the-vm)
|
||
#:language (lookup-language lang)
|
||
#:options repl-default-options
|
||
#:tm-stats (times)
|
||
#:gc-stats (gc-stats)
|
||
#:vm-stats (vm-stats (the-vm))))
|
||
|
||
(define (repl-welcome repl)
|
||
(let ((language (repl-language repl)))
|
||
(format #t "~A interpreter ~A on Guile ~A\n"
|
||
(language-title language) (language-version language) (version)))
|
||
(display "Copyright (C) 2001-2008 Free Software Foundation, Inc.\n\n")
|
||
(display "Enter `,help' for help.\n"))
|
||
|
||
(define (repl-prompt repl)
|
||
(format #f "~A@~A> " (language-name (repl-language repl))
|
||
(module-name (current-module))))
|
||
|
||
(define (repl-read repl)
|
||
((language-reader (repl-language repl))))
|
||
|
||
(define (repl-compile repl form . opts)
|
||
(let ((to (lookup-language (cond ((memq #:e opts) 'scheme)
|
||
((memq #:t opts) 'ghil)
|
||
((memq #:c opts) 'glil)
|
||
(else 'objcode)))))
|
||
(compile form #:from (repl-language repl) #:to to #:opts opts)))
|
||
|
||
(define (repl-parse repl form)
|
||
(let ((parser (language-parser (repl-language repl))))
|
||
(if parser (parser form) form)))
|
||
|
||
(define (repl-eval repl form)
|
||
(let ((eval (language-evaluator (repl-language repl))))
|
||
(if (and eval
|
||
(or (null? (language-compilers (repl-language repl)))
|
||
(assq-ref (repl-options repl) 'interp)))
|
||
(eval form (current-module))
|
||
(vm-load (repl-vm repl) (repl-compile repl form '())))))
|
||
|
||
(define (repl-print repl val)
|
||
(if (not (eq? val *unspecified*))
|
||
(begin
|
||
;; The result of an evaluation is representable in scheme, and
|
||
;; should be printed with the generic printer, `write'. The
|
||
;; language-printer is something else: it prints expressions of
|
||
;; a given language, not the result of evaluation.
|
||
(write val)
|
||
(newline))))
|
||
|
||
(define (repl-option-ref repl key)
|
||
(assq-ref (repl-options repl) key))
|
||
|
||
(define (repl-option-set! repl key val)
|
||
(set! (repl-options repl) (assq-set! (repl-options repl) key val)))
|
||
|
||
|
||
;;;
|
||
;;; Utilities
|
||
;;;
|
||
|
||
(define (puts x) (display x) (newline))
|
||
|
||
(define (->string x)
|
||
(object->string x display))
|
||
|
||
(define (user-error msg . args)
|
||
(throw 'user-error #f msg args #f))
|