mirror of
https://git.savannah.gnu.org/git/guile.git
synced 2025-05-01 12:20:26 +02:00
c5cc65ac0c
* module/ice-9/psyntax-pp.scm: Regenerate. * module/ice-9/psyntax.scm (syntax-type): Look up the type of the car of a form relative to its module, if it is a syntax object. Fixes hygiene wrt modules and private macros. * module/ice-9/syncase.scm (sc-macro): Add a comment. * module/system/base/pmatch.scm: The big test case: just export pmatch, not ppat too.
42 lines
1.4 KiB
Scheme
42 lines
1.4 KiB
Scheme
(define-module (system base pmatch)
|
||
#:use-module (ice-9 syncase)
|
||
#:export (pmatch))
|
||
;; FIXME: shouldn't have to export ppat...
|
||
|
||
;; Originally written by Oleg Kiselyov. Taken from:
|
||
;; αKanren: A Fresh Name in Nominal Logic Programming
|
||
;; by William E. Byrd and Daniel P. Friedman
|
||
;; Proceedings of the 2007 Workshop on Scheme and Functional Programming
|
||
;; Université Laval Technical Report DIUL-RT-0701
|
||
|
||
;; Licensing unclear. Probably need to ask Oleg for a disclaimer.
|
||
|
||
(define-syntax pmatch
|
||
(syntax-rules (else guard)
|
||
((_ (op arg ...) cs ...)
|
||
(let ((v (op arg ...)))
|
||
(pmatch v cs ...)))
|
||
((_ v) (if #f #f))
|
||
((_ v (else e0 e ...)) (begin e0 e ...))
|
||
((_ v (pat (guard g ...) e0 e ...) cs ...)
|
||
(let ((fk (lambda () (pmatch v cs ...))))
|
||
(ppat v pat
|
||
(if (and g ...) (begin e0 e ...) (fk))
|
||
(fk))))
|
||
((_ v (pat e0 e ...) cs ...)
|
||
(let ((fk (lambda () (pmatch v cs ...))))
|
||
(ppat v pat (begin e0 e ...) (fk))))))
|
||
|
||
(define-syntax ppat
|
||
(syntax-rules (_ quote unquote)
|
||
((_ v _ kt kf) kt)
|
||
((_ v () kt kf) (if (null? v) kt kf))
|
||
((_ v (quote lit) kt kf)
|
||
(if (equal? v (quote lit)) kt kf))
|
||
((_ v (unquote var) kt kf) (let ((var v)) kt))
|
||
((_ v (x . y) kt kf)
|
||
(if (pair? v)
|
||
(let ((vx (car v)) (vy (cdr v)))
|
||
(ppat vx x (ppat vy y kt kf) kf))
|
||
kf))
|
||
((_ v lit kt kf) (if (eq? v (quote lit)) kt kf))))
|